aboutsummaryrefslogblamecommitdiff
path: root/vim/after/ftplugin/perl.vim
blob: a303fa75e1e4b2e3d472a190187b8d50b1cdc4b9 (plain) (tree)
1
2
3
4
5
6
7
8
9


                                                         

                                                     
 

                                                              
                                              
 



                                                          
                                                      
                                                     


        
                               





                                                
 
                             
                                
                               
                                
                                     
                                                        
                                           

                      
                            
                                    
                            
                                    
                                                        
                                           
" Use Perl itself for checking and Perl::Tidy for tidying
compiler perl
setlocal equalprg=perltidy
let b:undo_ftplugin .= '|unlet b:current_compiler'
      \ . '|setlocal equalprg< errorformat< makeprg<'

" Add angle brackets to pairs of matched characters for q<...>
setlocal matchpairs+=<:>
let b:undo_ftplugin .= '|setlocal matchpairs<'

" Specify ERE regex (close to perlre) for regex_escape.vim
let b:regex_escape_flavor = 'ere'
let b:undo_ftplugin .= '|unlet b:regex_escape_flavor'

" Stop here if the user doesn't want ftplugin mappings
if exists('no_plugin_maps') || exists('no_perl_maps')
  finish
endif

" Add boilerplate intelligently
command -buffer Boilerplate
      \ call perl#Boilerplate()
nnoremap <buffer> <LocalLeader>b
      \ :<C-U>Boilerplate<CR>
let b:undo_ftplugin .= '|delcommand Boilerplate'
      \ . '|nunmap <buffer> <LocalLeader>b'

" Mappings to choose compiler
nnoremap <buffer> <LocalLeader>c
      \ :<C-U>compiler perl<CR>
nnoremap <buffer> <LocalLeader>l
      \ :<C-U>compiler perlcritic<CR>
let b:undo_ftplugin .= '|nunmap <buffer> <LocalLeader>c'
      \ . '|nunmap <buffer> <LocalLeader>l'

" Bump version numbers
nmap <buffer> <LocalLeader>v
      \ <Plug>(PerlVersionBumpMinor)
nmap <buffer> <LocalLeader>V
      \ <Plug>(PerlVersionBumpMajor)
let b:undo_ftplugin .= '|nunmap <buffer> <LocalLeader>v'
      \ . '|nunmap <buffer> <LocalLeader>V'