aboutsummaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorTom Ryder <tom@sanctum.geek.nz>2017-11-23 15:44:26 +1300
committerTom Ryder <tom@sanctum.geek.nz>2017-11-23 15:44:26 +1300
commitf4fff12f339fa5a17794bf64e541fe755715c792 (patch)
treec0d267e8470d380ba01cc2638dc07f1c475cb0d5
parentMerge branch 'hotfix/v0.19.1' into develop (diff)
downloaddotfiles-f4fff12f339fa5a17794bf64e541fe755715c792.tar.gz
dotfiles-f4fff12f339fa5a17794bf64e541fe755715c792.zip
Add syntax checking with zsh -n for Z shell
-rw-r--r--vim/after/ftplugin/zsh/check.vim49
-rw-r--r--vim/compiler/zsh.vim17
2 files changed, 66 insertions, 0 deletions
diff --git a/vim/after/ftplugin/zsh/check.vim b/vim/after/ftplugin/zsh/check.vim
new file mode 100644
index 00000000..39faf44a
--- /dev/null
+++ b/vim/after/ftplugin/zsh/check.vim
@@ -0,0 +1,49 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_zsh_check') || &compatible
+ finish
+endif
+let b:did_ftplugin_zsh_check = 1
+if exists('b:undo_ftplugin')
+ let b:undo_ftplugin = b:undo_ftplugin
+ \ . '|unlet b:did_ftplugin_zsh_check'
+endif
+
+" Build function for checker
+if !exists('*s:ZshCheck')
+ function s:ZshCheck()
+ let l:save_makeprg = &l:makeprg
+ let l:save_errorformat = &l:errorformat
+ unlet! g:current_compiler
+ compiler zsh
+ make!
+ let &l:makeprg = l:save_makeprg
+ let &l:errorformat = l:save_errorformat
+ cwindow
+ endfunction
+endif
+
+" Set up a mapping for the checker, if we're allowed
+if !exists('g:no_plugin_maps') && !exists('g:no_zsh_maps')
+
+ " Define a mapping target
+ nnoremap <buffer> <silent> <unique>
+ \ <Plug>ZshCheck
+ \ :<C-U>call <SID>ZshCheck()<CR>
+ if exists('b:undo_ftplugin')
+ let b:undo_ftplugin = b:undo_ftplugin
+ \ . '|nunmap <buffer> <Plug>ZshCheck'
+ endif
+
+ " If there isn't a key mapping already, use a default one
+ if !hasmapto('<Plug>ZshCheck')
+ nmap <buffer> <unique>
+ \ <LocalLeader>c
+ \ <Plug>ZshCheck
+ if exists('b:undo_ftplugin')
+ let b:undo_ftplugin = b:undo_ftplugin
+ \ . '|nunmap <buffer> <LocalLeader>c'
+ endif
+ endif
+
+endif
diff --git a/vim/compiler/zsh.vim b/vim/compiler/zsh.vim
new file mode 100644
index 00000000..685a01ad
--- /dev/null
+++ b/vim/compiler/zsh.vim
@@ -0,0 +1,17 @@
+if exists('g:current_compiler')
+ finish
+endif
+let g:current_compiler = 'zsh'
+
+if exists(':CompilerSet') != 2
+ command -nargs=* CompilerSet setlocal <args>
+endif
+
+" 7.4.191 is the earliest version with the :S file name modifier, which we
+" really should use if we can
+if v:version >= 704 || v:version == 704 && has('patch191')
+ CompilerSet makeprg=zsh\ -n\ %:S
+else
+ CompilerSet makeprg=zsh\ -n\ %
+endif
+CompilerSet errorformat=%f:%l:\ %m