aboutsummaryrefslogtreecommitdiff
path: root/vim/plugin/big_file_options.vim
diff options
context:
space:
mode:
authorTom Ryder <tom@sanctum.geek.nz>2017-11-04 20:16:43 +1300
committerTom Ryder <tom@sanctum.geek.nz>2017-11-04 20:19:53 +1300
commit79d6eef63ff4984fa3f8631aec6da26fa19a6f34 (patch)
treefbdd211ef98f26a03553134c29d46b72043f6367 /vim/plugin/big_file_options.vim
parentf64a85316734b7c22cd2fd2e9a87209683b5152b (diff)
downloaddotfiles-79d6eef63ff4984fa3f8631aec6da26fa19a6f34.tar.gz
dotfiles-79d6eef63ff4984fa3f8631aec6da26fa19a6f34.zip
Adjust plugin code layout a lot
Including renaming big_file.vim and accompanying functions yet again, to big_file_options.vim. Trying to keep complex autocmd and mapping definitions on long lines broken up semantically; definition and options on one line, patterns or mapping key on the next, and the command to run on the last. Also trying to make sure that <silent>, <buffer>, and <unique> are applied in the correct places, and that all mapping commands are using the :<C-U> idiom for the command prefix.
Diffstat (limited to 'vim/plugin/big_file_options.vim')
-rw-r--r--vim/plugin/big_file_options.vim62
1 files changed, 62 insertions, 0 deletions
diff --git a/vim/plugin/big_file_options.vim b/vim/plugin/big_file_options.vim
new file mode 100644
index 00000000..fd686fd8
--- /dev/null
+++ b/vim/plugin/big_file_options.vim
@@ -0,0 +1,62 @@
+"
+" big_file_options.vim: When opening a large file, take some measures to keep
+" things loading quickly.
+"
+" Author: Tom Ryder <tom@sanctum.geek.nz>
+" License: Same as Vim itself
+"
+if has('eval') && has('autocmd')
+
+ " Default threshold is 10 MiB
+ if !exists('g:big_file_size')
+ let g:big_file_size = 10 * 1024 * 1024
+ endif
+
+ " Default to leaving syntax highlighting off
+ if !exists('g:big_file_syntax')
+ let g:big_file_syntax = 0
+ endif
+
+ " Cut 'synmaxcol' down to this or smaller for big files
+ if !exists('g:big_file_synmaxcol')
+ let g:big_file_synmaxcol = 256
+ endif
+
+ " Declare function for turning off slow options
+ function! s:BigFileOptions()
+
+ " Don't do anything if the file is under the threshold
+ if getfsize(expand('<afile>')) <= g:big_file_size
+ return
+ endif
+
+ " Turn off backups, swap files, and undo files
+ setlocal nobackup
+ setlocal nowritebackup
+ setlocal noswapfile
+ if has('persistent_undo')
+ setlocal noundofile
+ endif
+
+ " Limit the number of columns of syntax highlighting
+ if exists('&synmaxcol')
+ \ && &synmaxcol > g:big_file_synmaxcol
+ execute 'setlocal synmaxcol=' . g:big_file_synmaxcol
+ endif
+
+ " Disable syntax highlighting if configured to do so
+ if !g:big_file_syntax
+ setlocal syntax=OFF
+ endif
+
+ endfunction
+
+ " Define autocmd for calling to check filesize
+ augroup big_file_options_bufreadpre
+ autocmd!
+ autocmd BufReadPre
+ \ *
+ \ call s:BigFileOptions()
+ augroup end
+
+endif