3 files changed, 125 insertions, 0 deletions
diff --git a/vim/after/ftplugin/html/lint.vim b/vim/after/ftplugin/html/lint.vim
new file mode 100644
index 00000000..3ac760ed
--- /dev/null
+++ b/vim/after/ftplugin/html/lint.vim
@@ -0,0 +1,37 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_html_lint') || &compatible
+  finish
+endif
+let b:did_ftplugin_html_lint = 1
+
+" Initialise undo variable if not already done
+if exists('b:undo_ftplugin')
+  let b:undo_ftplugin = b:undo_ftplugin
+        \ . '|unlet b:did_ftplugin_html_lint'
+endif
+
+" Set up a mapping for the linter, if we're allowed
+if !exists('g:no_plugin_maps') && !exists('g:no_html_maps')
+
+  " Define a mapping target
+  nnoremap <buffer> <silent> <unique>
+        \ <Plug>HtmlLint
+        \ :<C-U>write !tidy -errors -quiet<CR>
+  if exists('b:undo_ftplugin')
+    let b:undo_ftplugin = b:undo_ftplugin
+          \ . '|nunmap <buffer> <Plug>HtmlLint'
+  endif
+
+  " If there isn't a key mapping already, use a default one
+  if !hasmapto('<Plug>HtmlLint')
+    nmap <buffer> <unique>
+          \ <LocalLeader>l
+          \ <Plug>HtmlLint
+    if exists('b:undo_ftplugin')
+      let b:undo_ftplugin = b:undo_ftplugin
+            \ . '|nunmap <buffer> <LocalLeader>l'
+    endif
+  endif
+
+endif
diff --git a/vim/after/ftplugin/html/tidy.vim b/vim/after/ftplugin/html/tidy.vim
new file mode 100644
index 00000000..519a7cd6
--- /dev/null
+++ b/vim/after/ftplugin/html/tidy.vim
@@ -0,0 +1,35 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_html_tidy') || &compatible
+  finish
+endif
+let b:did_ftplugin_html_tidy = 1
+if exists('b:undo_ftplugin')
+  let b:undo_ftplugin = b:undo_ftplugin
+        \ . '|unlet b:did_ftplugin_html_tidy'
+endif
+
+" Set up a mapping for the tidier, if we're allowed
+if !exists('g:no_plugin_maps') && !exists('g:no_html_maps')
+
+  " Define a mapping target
+  nnoremap <buffer> <silent> <unique>
+        \ <Plug>HtmlTidy
+        \ :<C-U>%!tidy -quiet<CR>
+  if exists('b:undo_ftplugin')
+    let b:undo_ftplugin = b:undo_ftplugin
+          \ . '|nunmap <buffer> <Plug>HtmlTidy'
+  endif
+
+  " If there isn't a key mapping already, use a default one
+  if !hasmapto('<Plug>HtmlTidy')
+    nmap <buffer> <unique>
+          \ <LocalLeader>t
+          \ <Plug>HtmlTidy
+    if exists('b:undo_ftplugin')
+      let b:undo_ftplugin = b:undo_ftplugin
+            \ . '|nunmap <buffer> <LocalLeader>t'
+    endif
+  endif
+
+endif
diff --git a/vim/after/ftplugin/html/url_link.vim b/vim/after/ftplugin/html/url_link.vim
new file mode 100644
index 00000000..4f2d2526
--- /dev/null
+++ b/vim/after/ftplugin/html/url_link.vim
@@ -0,0 +1,53 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_html_url_link') || &compatible
+  finish
+endif
+let b:did_ftplugin_html_url_link = 1
+if exists('b:undo_ftplugin')
+  let b:undo_ftplugin = b:undo_ftplugin
+        \ . '|unlet b:did_ftplugin_html_url_link'
+endif
+
+" Make a bare URL into a link to itself
+if !exists('*s:UrlLink')
+  function! s:UrlLink()
+
+    " Yank this whole whitespace-separated word
+    normal! yiW
+    " Open a link tag
+    normal! i<a href="">
+    " Paste the URL into the quotes
+    normal! hP
+    " Move to the end of the link text URL
+    normal! E
+    " Close the link tag
+    normal! a</a>
+
+  endfunction
+endif
+
+" Set up a mapping for the function, if we're allowed
+if !exists('g:no_plugin_maps') && !exists('g:no_html_maps')
+
+  " Define a mapping target
+  nnoremap <buffer> <silent> <unique>
+        \ <Plug>HtmlUrlLink
+        \ :<C-U>call <SID>HtmlUrlLink()<CR>
+  if exists('b:undo_ftplugin')
+    let b:undo_ftplugin = b:undo_ftplugin
+          \ . '|nunmap <buffer> <Plug>HtmlUrlLink'
+  endif
+
+  " If there isn't a key mapping already, use a default one
+  if !hasmapto('<Plug>HtmlUrlLink')
+    nmap <buffer> <unique>
+          \ <LocalLeader>r
+          \ <Plug>HtmlUrlLink
+    if exists('b:undo_ftplugin')
+      let b:undo_ftplugin = b:undo_ftplugin
+            \ . '|nunmap <buffer> <LocalLeader>r'
+    endif
+  endif
+
+endif