4 files changed, 120 insertions, 0 deletions
diff --git a/vim/after/ftplugin/sh/bash_han.vim b/vim/after/ftplugin/sh/bash_han.vim
new file mode 100644
index 00000000..c1997d7e
--- /dev/null
+++ b/vim/after/ftplugin/sh/bash_han.vim
@@ -0,0 +1,15 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_sh_bash_han') || &compatible
+  finish
+endif
+let b:did_ftplugin_sh_bash_han = 1
+let b:undo_ftplugin = b:undo_ftplugin
+      \ . '|unlet b:did_ftplugin_sh_bash_han'
+
+" Use han(1df) as a man(1) wrapper for Bash files if available
+if exists('b:is_bash') && executable('han')
+  setlocal keywordprg=han
+  let b:undo_ftplugin = b:undo_ftplugin
+        \ . '|setlocal keywordprg<'
+endif
diff --git a/vim/after/ftplugin/sh/check.vim b/vim/after/ftplugin/sh/check.vim
new file mode 100644
index 00000000..5000137d
--- /dev/null
+++ b/vim/after/ftplugin/sh/check.vim
@@ -0,0 +1,40 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_sh_check') || &compatible
+  finish
+endif
+let b:did_ftplugin_sh_check = 1
+let b:undo_ftplugin = b:undo_ftplugin
+      \ . '|unlet b:did_ftplugin_sh_check'
+
+" Choose checker based on shell family
+if exists('b:is_bash')
+  let b:sh_check = 'write !bash -n'
+elseif exists('b:is_kornshell')
+  let b:sh_check = 'write !ksh -n'
+else
+  let b:sh_check = 'write !sh -n'
+endif
+let b:undo_ftplugin = b:undo_ftplugin
+      \ . '|unlet b:sh_check'
+
+" Set up a mapping for the checker, if we're allowed
+if !exists('g:no_plugin_maps') && !exists('g:no_sh_maps')
+
+  " Define a mapping target
+  nnoremap <buffer> <silent> <unique>
+        \ <Plug>ShCheck
+        \ :<C-U>execute b:sh_check<CR>
+  let b:undo_ftplugin = b:undo_ftplugin
+        \ . '|nunmap <buffer> <Plug>ShCheck'
+
+  " If there isn't a key mapping already, use a default one
+  if !hasmapto('<Plug>ShCheck')
+    nmap <buffer> <unique>
+          \ <LocalLeader>c
+          \ <Plug>ShCheck
+    let b:undo_ftplugin = b:undo_ftplugin
+          \ . '|nunmap <buffer> <LocalLeader>c'
+  endif
+
+endif
diff --git a/vim/after/ftplugin/sh/lint.vim b/vim/after/ftplugin/sh/lint.vim
new file mode 100644
index 00000000..54f86bea
--- /dev/null
+++ b/vim/after/ftplugin/sh/lint.vim
@@ -0,0 +1,40 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_sh_lint') || &compatible
+  finish
+endif
+let b:did_ftplugin_sh_lint = 1
+let b:undo_ftplugin = b:undo_ftplugin
+      \ . '|unlet b:did_ftplugin_sh_lint'
+
+" Choose linter based on shell family
+if exists('b:is_bash')
+  let b:sh_lint = 'write !shellcheck -s bash -'
+elseif exists('b:is_kornshell')
+  let b:sh_lint = 'write !shellcheck -s ksh -'
+else
+  let b:sh_lint = 'write !shellcheck -s sh -'
+endif
+let b:undo_ftplugin = b:undo_ftplugin
+      \ . '|unlet b:sh_lint'
+
+" Set up a mapping for the linter, if we're allowed
+if !exists('g:no_plugin_maps') && !exists('g:no_sh_maps')
+
+  " Define a mapping target
+  nnoremap <buffer> <silent> <unique>
+        \ <Plug>ShLint
+        \ :<C-U>execute b:sh_lint<CR>
+  let b:undo_ftplugin = b:undo_ftplugin
+        \ . '|nunmap <buffer> <Plug>ShLint'
+
+  " If there isn't a key mapping already, use a default one
+  if !hasmapto('<Plug>ShLint')
+    nmap <buffer> <unique>
+          \ <LocalLeader>l
+          \ <Plug>ShLint
+    let b:undo_ftplugin = b:undo_ftplugin
+          \ . '|nunmap <buffer> <LocalLeader>l'
+  endif
+
+endif
diff --git a/vim/after/ftplugin/sh/posix.vim b/vim/after/ftplugin/sh/posix.vim
new file mode 100644
index 00000000..ef6b9b93
--- /dev/null
+++ b/vim/after/ftplugin/sh/posix.vim
@@ -0,0 +1,25 @@
+" Only do this when not done yet for this buffer
+" Also do nothing if 'compatible' enabled
+if exists('b:did_ftplugin_sh_posix') || &compatible
+  finish
+endif
+let b:did_ftplugin_sh_posix = 1
+let b:undo_ftplugin = b:undo_ftplugin
+      \ . '|unlet b:did_ftplugin_sh_posix'
+
+"
+" If we have a #!/bin/sh shebang and filetype.vim determined we were neither
+" POSIX nor Bash nor Korn shell, we'll guess POSIX, just because it's far more
+" likely that's what I want to write than plain Bourne shell.
+"
+" You're supposed to be able to do this by setting g:is_posix, but if that's
+" set, the syntax file ends up setting g:is_kornshell for you too, for reasons
+" I don't really understand. This method works though, and is cleaner than
+" the other workaround I had been trying.
+"
+if exists('b:is_sh')
+  unlet b:is_sh
+  if !exists('b:is_bash') && !exists('b:is_kornshell')
+    let b:is_posix = 1
+  endif
+endif