From af3569d8a74c744770e77f2b2b8d7956c5d6f8c0 Mon Sep 17 00:00:00 2001
From: Tom Ryder <tom@sanctum.geek.nz>
Date: Tue, 3 Jul 2018 17:30:38 +1200
Subject: Add _v/_V Vim maps for Perl version bumps

---
 vim/after/ftplugin/perl.vim |  9 +++++++++
 vim/autoload/perl.vim       | 28 ++++++++++++++++++++++++++++
 2 files changed, 37 insertions(+)
 create mode 100644 vim/autoload/perl.vim

(limited to 'vim')

diff --git a/vim/after/ftplugin/perl.vim b/vim/after/ftplugin/perl.vim
index e9747aa3..37cd1c08 100644
--- a/vim/after/ftplugin/perl.vim
+++ b/vim/after/ftplugin/perl.vim
@@ -25,3 +25,12 @@ let b:undo_ftplugin = b:undo_ftplugin
       \ . '|nunmap <buffer> <LocalLeader>c'
       \ . '|nunmap <buffer> <LocalLeader>l'
       \ . '|nunmap <buffer> <LocalLeader>t'
+
+" Bump version numbers
+nnoremap <buffer> <LocalLeader>v
+      \ :<C-U>call perl#BumpVersionMinor()<CR>
+nnoremap <buffer> <LocalLeader>V
+      \ :<C-U>call perl#BumpVersionMajor()<CR>
+let b:undo_ftplugin = b:undo_ftplugin
+      \ . '|nunmap <buffer> <LocalLeader>v'
+      \ . '|nunmap <buffer> <LocalLeader>V'
diff --git a/vim/autoload/perl.vim b/vim/autoload/perl.vim
new file mode 100644
index 00000000..ca9b2990
--- /dev/null
+++ b/vim/autoload/perl.vim
@@ -0,0 +1,28 @@
+" Quick-and-dirty version number bumper
+function! perl#BumpVersion(major) abort
+  let l:view = winsaveview()
+  let l:search = @/
+  let l:li = search('\C^our \$VERSION\s*=')
+  if !l:li
+    echomsg 'No version number declaration found'
+    return
+  endif
+  if a:major
+    silent execute "normal! /[0-9]\<CR>\<C-A>"
+    echomsg 'Major version bumped: '.getline('.')
+  else
+    silent execute "normal! $?[0-9]\<CR>\<C-A>"
+    echomsg 'Minor version bumped: '.getline('.')
+  endif
+  let @/ = l:search
+  call winrestview(l:view)
+endfunction
+
+" Explanatory wrappers
+function! perl#BumpVersionMinor() abort
+  call perl#BumpVersion(0)
+endfunction
+
+function! perl#BumpVersionMajor() abort
+  call perl#BumpVersion(1)
+endfunction
-- 
cgit v1.2.3