aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/html/lint.vim
blob: b24b18c96e31fb73efd45f551225596af7ef9aa1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
" Only do this when not done yet for this buffer
" Also do nothing if 'compatible' enabled, or if the current filetype is
" actually markdown
if exists('b:did_ftplugin_html_lint') || &compatible
  finish
endif
if &filetype ==# 'markdown'
  finish
endif
let b:did_ftplugin_html_lint = 1

" Initialise undo variable if not already done
if exists('b:undo_ftplugin')
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|unlet b:did_ftplugin_html_lint'
endif

" Build function for linter
if !exists('*s:HtmlLint')
  function s:HtmlLint()
    let l:save_makeprg = &l:makeprg
    let l:save_errorformat = &l:errorformat
    unlet! g:current_compiler
    compiler tidy
    make!
    let &l:makeprg = l:save_makeprg
    let &l:errorformat = l:save_errorformat
    cwindow
  endfunction
endif

" Set up a mapping for the linter, if we're allowed
if !exists('g:no_plugin_maps') && !exists('g:no_html_maps')

  " Define a mapping target
  nnoremap <buffer> <silent> <unique>
        \ <Plug>HtmlLint
        \ :<C-U>call <SID>HtmlLint()<CR>
  if exists('b:undo_ftplugin')
    let b:undo_ftplugin = b:undo_ftplugin
          \ . '|nunmap <buffer> <Plug>HtmlLint'
  endif

  " If there isn't a key mapping already, use a default one
  if !hasmapto('<Plug>HtmlLint')
    nmap <buffer> <unique>
          \ <LocalLeader>l
          \ <Plug>HtmlLint
    if exists('b:undo_ftplugin')
      let b:undo_ftplugin = b:undo_ftplugin
            \ . '|nunmap <buffer> <LocalLeader>l'
    endif
  endif

endif