aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/html/tidy.vim
blob: 270e54e2e33839455787161e9f230626b18b99c6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
" Only do this when not done yet for this buffer
" Also do nothing if 'compatible' enabled, or if the current filetype is
" actually markdown
if exists('b:did_ftplugin_html_tidy') || &compatible
  finish
endif
if &filetype == 'markdown'
  finish
endif
let b:did_ftplugin_html_tidy = 1
if exists('b:undo_ftplugin')
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|unlet b:did_ftplugin_html_tidy'
endif

" Set up a mapping for the tidier, if we're allowed
if !exists('g:no_plugin_maps') && !exists('g:no_html_maps')

  " Define a mapping target
  nnoremap <buffer> <silent> <unique>
        \ <Plug>HtmlTidy
        \ :<C-U>%!tidy -quiet<CR>
  if exists('b:undo_ftplugin')
    let b:undo_ftplugin = b:undo_ftplugin
          \ . '|nunmap <buffer> <Plug>HtmlTidy'
  endif

  " If there isn't a key mapping already, use a default one
  if !hasmapto('<Plug>HtmlTidy')
    nmap <buffer> <unique>
          \ <LocalLeader>t
          \ <Plug>HtmlTidy
    if exists('b:undo_ftplugin')
      let b:undo_ftplugin = b:undo_ftplugin
            \ . '|nunmap <buffer> <LocalLeader>t'
    endif
  endif

endif