aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/html/url_link.vim
blob: 1cf57a7bdcdb960c8ad6de255f00d04e2283cad1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
" html/url_link.vim: Make a URL into a link

" Don't load if running compatible or too old
if &compatible || v:version < 700
  finish
endif

" Don't load if already loaded
if exists('b:did_ftplugin_html_url_link')
  finish
endif

" Don't load if the primary filetype isn't HTML
if &filetype !=# 'html'
  finish
endif

" Flag as loaded
let b:did_ftplugin_html_url_link = 1
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|unlet b:did_ftplugin_html_url_link'

" Make a bare URL into a link to itself
function! s:HtmlUrlLink()

  " Yank this whole whitespace-separated word
  normal! yiW
  " Open a link tag
  normal! i<a href="">
  " Paste the URL into the quotes
  normal! hP
  " Move to the end of the link text URL
  normal! E
  " Close the link tag
  normal! a</a>

endfunction

" Stop here if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_html_maps')
  finish
endif

" Define a mapping target
nnoremap <buffer> <silent> <unique>
      \ <Plug>HtmlUrlLink
      \ :<C-U>call <SID>HtmlUrlLink()<CR>
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|nunmap <buffer> <Plug>HtmlUrlLink'

" If there isn't a key mapping already, use a default one
if !hasmapto('<Plug>HtmlUrlLink')
  nmap <buffer> <unique>
        \ <LocalLeader>r
        \ <Plug>HtmlUrlLink
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|nunmap <buffer> <LocalLeader>r'
endif