aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/perl/check.vim
blob: f6f99f083a21cd185692ac7af4ba9f04e843466e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
" perl/check.vim: Use Perl binary to check for errors

" Don't load if running compatible or too old
if &compatible || v:version < 700
  finish
endif

" Don't load if already loaded
if exists('b:did_ftplugin_perl_check')
  finish
endif

" Don't load if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_perl_maps')
  finish
endif

" Flag as loaded
let b:did_ftplugin_perl_check = 1
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|unlet b:did_ftplugin_perl_check'

" Define a mapping target
nnoremap <buffer> <silent> <unique>
      \ <Plug>PerlCheck
      \ :<C-U>call compiler#Make('perl')<CR>
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|nunmap <buffer> <Plug>PerlCheck'

" If there isn't a key mapping already, use a default one
if !hasmapto('<Plug>PerlCheck')
  nmap <buffer> <unique>
        \ <LocalLeader>c
        \ <Plug>PerlCheck
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|nunmap <buffer> <LocalLeader>c'
endif