aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/perl/tidy.vim
blob: 18033a42c53af038d54075a3259dede00a6523aa (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
" Only do this when not done yet for this buffer
" Also do nothing if 'compatible' enabled
if exists('b:did_ftplugin_perl_tidy') || &compatible
  finish
endif
let b:did_ftplugin_perl_tidy = 1
if exists('b:undo_ftplugin')
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|unlet b:did_ftplugin_perl_tidy'
endif

" Set up a mapping for the tidier, if we're allowed
if !exists('g:no_plugin_maps') && !exists('g:no_perl_maps')

  " Define a mapping target
  nnoremap <buffer> <silent> <unique>
        \ <Plug>PerlTidy
        \ :<C-U>%!perltidy<CR>
  if exists('b:undo_ftplugin')
    let b:undo_ftplugin = b:undo_ftplugin
          \ . '|nunmap <buffer> <Plug>PerlTidy'
  endif

  " If there isn't a key mapping already, use a default one
  if !hasmapto('<Plug>PerlTidy')
    nmap <buffer> <unique>
          \ <LocalLeader>t
          \ <Plug>PerlTidy
    if exists('b:undo_ftplugin')
      let b:undo_ftplugin = b:undo_ftplugin
            \ . '|nunmap <buffer> <LocalLeader>t'
    endif
  endif

endif