aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/php.vim
blob: 9b7c2bb0577cf46bc145de7c269f382bedd93138 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
" Extra configuration for PHP scripts
if &filetype !=# 'php' || v:version < 700 || &compatible
  finish
endif

" Use PHP itself for syntax checking
compiler php
let b:undo_ftplugin .= '|unlet b:current_compiler'
      \ . '|setlocal errorformat< makeprg<'

" Set comment formats
setlocal comments=s1:/*,m:*,ex:*/,://,:#
setlocal formatoptions+=or
let b:undo_ftplugin .= '|setlocal comments< formatoptions<'

" Use pman as 'keywordprg'
setlocal keywordprg=pman
let b:undo_ftplugin .= '|setlocal keywordprg<'

" Stop here if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_php_maps')
  finish
endif

" Get rid of the core ftplugin's square-bracket maps on unload
let b:undo_ftplugin .= '|nunmap <buffer> [['
      \ . '|ounmap <buffer> [['
      \ . '|nunmap <buffer> ]]'
      \ . '|ounmap <buffer> ]]'