aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/php/check.vim
blob: 9dc4c6a8dbb0aeeae7c04c607a8a88211c35865c (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
" php/check.vim: Use PHP binary to check scripts for errors

" Don't load if running compatible or too old
if &compatible || v:version < 700
  finish
endif

" Don't load if already loaded
if exists('b:did_ftplugin_php_check')
  finish
endif

" Don't load if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_php_maps')
  finish
endif

" Flag as loaded
let b:did_ftplugin_php_check = 1
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|unlet b:did_ftplugin_php_check'

" Define a mapping target
nnoremap <buffer> <silent> <unique>
      \ <Plug>PhpCheck
      \ :<C-U>call compiler#Make('php')<CR>
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|nunmap <buffer> <Plug>PhpCheck'

" If there isn't a key mapping already, use a default one
if !hasmapto('<Plug>PhpCheck')
  nmap <buffer> <unique>
        \ <LocalLeader>c
        \ <Plug>PhpCheck
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|nunmap <buffer> <LocalLeader>c'
endif