aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/sh/lint.vim
blob: 87f1c07e934120b923c80d9f5ce5ca71103bdbd6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
" sh/lint.vim: Use appropriate shell binary to lint scripts for errors

" Don't load if running compatible or too old
if &compatible || v:version < 700
  finish
endif

" Don't load if already loaded
if exists('b:did_ftplugin_sh_lint')
  finish
endif

" Flag as loaded
let b:did_ftplugin_sh_lint = 1
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|unlet b:did_ftplugin_sh_lint'

" Build function for linter
function! s:ShLint()
  if exists('b:current_compiler')
    let l:save_compiler = b:current_compiler
  endif
  compiler shellcheck
  lmake!
  lwindow
  if exists('l:save_compiler')
    execute 'compiler ' . l:save_compiler
  endif
endfunction

" Stop here if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_sh_maps')
  finish
endif

" Define a mapping target
nnoremap <buffer> <silent> <unique>
      \ <Plug>ShLint
      \ :<C-U>call <SID>ShLint()<CR>
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|nunmap <buffer> <Plug>ShLint'

" If there isn't a key mapping already, use a default one
if !hasmapto('<Plug>ShLint')
  nmap <buffer> <unique>
        \ <LocalLeader>l
        \ <Plug>ShLint
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|nunmap <buffer> <LocalLeader>l'
endif