aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/vim/lint.vim
blob: 1e4f7d39c337a9a761e345b2ec0855075c3964bf (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
" vim/lint.vim: Use Vint to lint VimL scripts

" Don't load if running compatible or too old
if &compatible || v:version < 700
  finish
endif

" Don't load if already loaded
if exists('b:did_ftplugin_vim_lint')
  finish
endif

" Flag as loaded
let b:did_ftplugin_vim_lint = 1
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|unlet b:did_ftplugin_vim_lint'

" Build function for linter
function! s:VimLint()
  if exists('b:current_compiler')
    let l:save_compiler = b:current_compiler
  endif
  compiler vint
  lmake!
  lwindow
  if exists('l:save_compiler')
    execute 'compiler ' . l:save_compiler
  endif
endfunction

" Stop here if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_vim_maps')
  finish
endif

" Define a mapping target
nnoremap <buffer> <silent> <unique>
      \ <Plug>VimLint
      \ :<C-U>call <SID>VimLint()<CR>
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|nunmap <buffer> <Plug>VimLint'

" If there isn't a key mapping already, use a default one
if !hasmapto('<Plug>VimLint')
  nmap <buffer> <unique>
        \ <LocalLeader>l
        \ <Plug>VimLint
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|nunmap <buffer> <LocalLeader>l'
endif