aboutsummaryrefslogtreecommitdiff
path: root/vim/autoload/mail.vim
blob: 40b7fb7f834e2a9d83db690b35220934d507a05c (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
" Add a header to a mail message
function! mail#AddHeaderField(name, body) abort
  let num = 0
  while num < line('$') && getline(num + 1) !=# ''
    let num += 1
  endwhile
  call append(num, a:name.': '.a:body)
endfunction

" Add a set of headers to a mail message
function! mail#AddHeaderFields(fields) abort
  for name in sort(keys(a:fields))
    call mail#AddHeaderField(name, a:fields[name])
  endfor
endfunction

" Flag a message as important
function! mail#FlagImportant() abort
  call mail#AddHeaderFields({
        \ 'Importance': 'High',
        \ 'X-Priority': 1
        \ })
endfunction

" Flag a message as unimportant
function! mail#FlagUnimportant() abort
  call mail#AddHeaderFields({
        \ 'Importance': 'Low',
        \ 'X-Priority': 5
        \ })
endfunction

" Move through quoted paragraphs like normal-mode `{` and `}`
function! mail#NewBlank(count, up, visual) abort

  " Reselect visual selection
  if a:visual
    normal! gv
  endif

  " Flag for whether we've started a block
  let block = 0

  " Flag for the number of blocks passed
  let blocks = 0

  " Iterate through buffer lines
  let num = line('.')
  while a:up ? num > 1 : num < line('$')

    " If the line is blank
    if getline(num) =~# '^[ >]*$'

      " If we'd moved through a non-blank block already, reset that flag and
      " bump up the block count
      if block
        let block = 0
        let blocks += 1
      endif

      " If we've hit the number of blocks, end the loop
      if blocks == a:count
        break
      endif

    " If the line is not blank, flag that we're going through a block
    else
      let block = 1
    endif

    " Move the line number or up or down depending on direction
    let num += a:up ? -1 : 1

  endwhile

  " Move to line if nonzero and not equal to the current line
  if num != line('.')
    execute 'normal '.num.'G'
  endif

endfunction