aboutsummaryrefslogtreecommitdiff
path: root/vim/plugin/auto_undodir.vim
blob: 0cd54cd023603dcf8cd0664901cdc15526095445 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
"
" auto_undodir.vim: Configure 'undodir' automatically, including trying hard
" to create it.
"
" Author: Tom Ryder <tom@sanctum.geek.nz>
" License: Same as Vim itself
"
if exists('g:loaded_auto_undodir') || &compatible
  finish
endif
if !has('persistent_undo')
  finish
endif
let g:loaded_auto_undodir = 1

" Define the undo path we want
if exists('$VIM_UNDODIR')
  let s:undodir = $VIM_UNDODIR
else

  " This is imperfect in that it will break if you have a backslashed comma in
  " the first component of your &runtimepath, but if you're doing that, you
  " probably already have way bigger problems
  let s:undodir
      \ = strpart(&runtimepath, 0, stridx(&runtimepath, ','))
      \ . '/undo'
endif

" If the prospective undo directory does not exist, try hard to create it
if !isdirectory(expand(s:undodir))

  " Try Vim's native mkdir() first
  if exists('*mkdir')
    silent! call mkdir(expand(s:undodir), 'p', 0700)

  " Failing that, use an OS-dependent command
  " (Fortunately, Unix and Windows are the only OS types in the world)
  elseif has('*shellescape')
    elseif has('unix')
      silent! execute '!mkdir -m 0700 -p '
            \ . shellescape(expand(s:undodir))
    elseif has('win32') || has('win64')
      silent! execute '!mkdir '
            \ . shellescape(expand(s:undodir))
    endif
  endif

endif

" If the directory exists after that...
if isdirectory(expand(s:undodir))

  " Set the undo directory and turn persistent undo files on
  execute 'set undodir^=' . s:undodir . '//'
  set undofile

" If not, give up and raise an error
else
  echoerr 'Could not create undodir ' . s:undodir
endif