aboutsummaryrefslogtreecommitdiff
path: root/vim/plugin/big_file_options.vim
blob: fd686fd897c3326868048e14a840a23716a62462 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
"
" big_file_options.vim: When opening a large file, take some measures to keep
" things loading quickly.
"
" Author: Tom Ryder <tom@sanctum.geek.nz>
" License: Same as Vim itself
"
if has('eval') && has('autocmd')

  " Default threshold is 10 MiB
  if !exists('g:big_file_size')
    let g:big_file_size = 10 * 1024 * 1024
  endif

  " Default to leaving syntax highlighting off
  if !exists('g:big_file_syntax')
    let g:big_file_syntax = 0
  endif

  " Cut 'synmaxcol' down to this or smaller for big files
  if !exists('g:big_file_synmaxcol')
    let g:big_file_synmaxcol = 256
  endif

  " Declare function for turning off slow options
  function! s:BigFileOptions()

    " Don't do anything if the file is under the threshold
    if getfsize(expand('<afile>')) <= g:big_file_size
      return
    endif

    " Turn off backups, swap files, and undo files
    setlocal nobackup
    setlocal nowritebackup
    setlocal noswapfile
    if has('persistent_undo')
      setlocal noundofile
    endif

    " Limit the number of columns of syntax highlighting
    if exists('&synmaxcol')
          \ && &synmaxcol > g:big_file_synmaxcol
      execute 'setlocal synmaxcol=' . g:big_file_synmaxcol
    endif

    " Disable syntax highlighting if configured to do so
    if !g:big_file_syntax
      setlocal syntax=OFF
    endif

  endfunction

  " Define autocmd for calling to check filesize
  augroup big_file_options_bufreadpre
    autocmd!
    autocmd BufReadPre
          \ *
          \ call s:BigFileOptions()
  augroup end

endif