blob: 82d1a7ddd73bbf8050f24c75ebd075b8168918af (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
"
" bigfile.vim: When opening a large file, take some measures to keep things
" loading quickly.
"
" Author: Tom Ryder <tom@sanctum.geek.nz>
" Copyright: 2017
" License: Same as Vim itself
"
if has('eval') && has('autocmd')
" Default threshold is 10 MiB
if !exists('g:bigfile_size')
let g:bigfile_size = 10 * 1024 * 1024
endif
" Declare function for turning off slow options
function! s:BigFileOptions(name, size)
" Don't do anything if the file is under the threshold
if getfsize(a:name) <= a:size
return
endif
" Turn off backups, swap files, and undo files
setlocal nobackup
setlocal nowritebackup
setlocal noswapfile
if has('persistent_undo')
setlocal noundofile
endif
" Limit the number of columns of syntax highlighting
if exists('&synmaxcol')
setlocal synmaxcol=256
endif
endfunction
" Define autocmd for calling to check filesize
augroup bigfile_options_bufreadpre
autocmd!
autocmd BufReadPre * call s:BigFileOptions(expand('<afile>'), g:bigfile_size)
augroup end
endif
|