aboutsummaryrefslogtreecommitdiff
path: root/vim/plugin/toggle_option_flag.vim
blob: cbe8035ece6fa041196c5c1f755efd2557f5a455 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
"
" toggle_option_flag.vim: Provide commands to toggle flags in single-char
" grouped options like 'formatoptions', 'shortmess', 'complete' etc.
"
" This will fail hilariously if you try to set e.g. 'switchbuf' with it!
"
" Author: Tom Ryder <tom@sanctum.geek.nz>
" License: Same as Vim itself
"
if exists('g:loaded_toggle_option_flag')
      \ || !has('user_commands')
      \ || &compatible
  finish
endif
let g:loaded_toggle_option_flag = 1

" Internal function to do the toggling
function! s:Toggle(option, flag, local)

  " Check for weird options, we don't want to :execute anything funny
  if a:option =~# '[^a-z]'
    echoerr 'Illegal option name'
    return
  endif

  " Weird flags, too; should be a single inoffensive char
  if a:flag !~# '^[a-z0-9.]$'
    echoerr 'Illegal flag'
    return
  endif

  " Choose which set command to use
  let l:set = a:local
        \ ? 'setlocal'
        \ : 'set'

  " :execute to assign -= or += to l:op for the option toggle
  " (I couldn't get {curly braces} indirection to work)
  let l:op = ''
  execute 'let l:op = &' . a:option . ' =~# a:flag ? "-=" : "+="'

  " :execute to perform the option toggle and then print the value
  execute l:set . ' ' . a:option . l:op . a:flag
  execute l:set . ' ' . a:option . '?'

endfunction

" User commands wrapping around calls to the above function
command -nargs=+ -complete=option
      \ ToggleOptionFlag
      \ call <SID>Toggle(<f-args>, 0)
command -nargs=+ -complete=option
      \ ToggleOptionFlagLocal
      \ call <SID>Toggle(<f-args>, 1)